diff --git a/Demo/Makefile.am b/Demo/Makefile.am
new file mode 100644
--- /dev/null
+++ b/Demo/Makefile.am
@@ -0,0 +1,30 @@
+AM_CPPFLAGS = -I$(top_srcdir)/Include $(SUITESPARSECONFIG_CFLAGS)
+LDADD = $(top_builddir)/Source/libcolamd.la
+
+EXTRA_DIST = \
+	colamd_example.out \
+	colamd_l_example.out
+
+# Disable the .out implicit pattern rule.  Prevents GNU make from
+# adding bogus dependencies for the .out files listed above.
+%.out: %
+
+check_PROGRAMS = \
+	colamd_example \
+	colamd_l_example
+
+colamd_example_SOURCES = colamd_example.c
+colamd_l_example_SOURCES = colamd_l_example.c
+
+check-local: $(check_PROGRAMS) $(check_PROGRAMS:=.out)
+	@for i in $(check_PROGRAMS); do \
+		echo "Testing $$i"; \
+		./$$i$(EXEEXT) > my_$$i.out; \
+		if diff -u $(srcdir)/$$i.out my_$$i.out; then \
+			echo "Test $$i PASSED."; \
+		else \
+			echo "Test $$i FAILED."; \
+		fi; \
+	done
+
+CLEANFILES = my_*.out
diff --git a/Include/Makefile.am b/Include/Makefile.am
new file mode 100644
--- /dev/null
+++ b/Include/Makefile.am
@@ -0,0 +1 @@
+pkginclude_HEADERS = colamd.h
diff --git a/Makefile.am b/Makefile.am
new file mode 100644
--- /dev/null
+++ b/Makefile.am
@@ -0,0 +1,5 @@
+SUBDIRS = Include Source Demo
+EXTRA_DIST = README.txt Doc/ChangeLog Doc/lesser.txt
+
+pkgconfigdir = $(libdir)/pkgconfig
+pkgconfig_DATA = colamd.pc
diff --git a/Source/Makefile.am b/Source/Makefile.am
new file mode 100644
--- /dev/null
+++ b/Source/Makefile.am
@@ -0,0 +1,18 @@
+AM_CPPFLAGS = -I$(top_srcdir)/Include $(SUITESPARSECONFIG_CFLAGS)
+
+COLAMDSRC = \
+	colamd.c
+
+lib_LTLIBRARIES = libcolamd.la
+noinst_LTLIBRARIES = libcolamdi.la libcolamdl.la
+
+libcolamdi_la_SOURCES = $(COLAMDSRC)
+libcolamdi_la_LIBADD = -lm
+
+libcolamdl_la_SOURCES = $(COLAMDSRC)
+libcolamdl_la_LIBADD = -lm
+libcolamdl_la_CPPFLAGS = $(AM_CPPFLAGS) -DDLONG
+
+libcolamd_la_SOURCES = colamd_global.c
+libcolamd_la_LIBADD = libcolamdi.la libcolamdl.la
+libcolamd_la_LDFLAGS = -no-undefined -version-number 2:8:0
diff --git a/colamd.pc.in b/colamd.pc.in
new file mode 100644
--- /dev/null
+++ b/colamd.pc.in
@@ -0,0 +1,13 @@
+prefix=@prefix@
+exec_prefix=@exec_prefix@
+libdir=@libdir@
+includedir=@includedir@
+
+Name: @PACKAGE_NAME@
+Description: Column approximate minimum degree ordering
+Version: @PACKAGE_VERSION@
+URL: @PACKAGE_URL@
+Requires.private: suitesparseconfig
+Libs: -L${libdir} -lcolamd
+Libs.private: -lm
+Cflags: -I${includedir}/colamd
diff --git a/configure.ac b/configure.ac
new file mode 100644
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,42 @@
+#                                               -*- Autoconf -*-
+# Process this file with autoconf to produce a configure script.
+
+AC_PREREQ([2.69])
+AC_INIT([COLAMD],[2.8.0],[DrTimothyAldenDavis@gmail.com],[colamd],[http://www.suitesparse.com/])
+AC_CONFIG_SRCDIR([Source/colamd_global.c])
+AC_CONFIG_HEADERS([config.h])
+AM_INIT_AUTOMAKE([foreign])
+LT_INIT
+
+# Checks for programs.
+AC_PROG_INSTALL
+AC_PROG_CC
+
+LIBS_SAVED=$LIBS
+
+# Checks for libraries.
+AC_CHECK_LIB([m], [sqrt])
+
+PKG_PROG_PKG_CONFIG
+PKG_CHECK_MODULES([SUITESPARSECONFIG],[suitesparseconfig],
+	[],
+	[AC_MSG_ERROR([cannot find suitesparseconfig])])
+
+# Checks for header files.
+AC_CHECK_HEADERS([limits.h stdlib.h])
+
+# Checks for typedefs, structures, and compiler characteristics.
+AC_TYPE_SIZE_T
+
+# Checks for library functions.
+AC_CHECK_FUNCS([sqrt])
+
+LIBS=$LIBS_SAVED
+
+AC_CONFIG_FILES([
+	colamd.pc
+	Makefile
+	Demo/Makefile
+	Include/Makefile
+	Source/Makefile])
+AC_OUTPUT